MyException - 我的异常网
当前位置:我的异常网» Flex » Flex与Java低数据量通讯息二:URLLoader及非视图组

Flex与Java低数据量通讯息二:URLLoader及非视图组件的事件发布订阅

www.MyException.Cn  网友分享于:2015-08-26  浏览:15次
Flex与Java低数据量通信息二:URLLoader及非视图组件的事件发布订阅

该实例使用URLLoader向服务器获取XML和txt(properties格式数据)数据,由于获取数据由URLLoader完成,我将些操作单独放到另一个as文件中,故与视图组件分开,那么如何通告视图组件已完成数据加载功能呢?我在自己的as文件中自定义了一个事件,当URLLoader完成数据加载时,发布自定义的事件并将数据随事件一起分布,再在视图组件中订阅自定义的事件。

 

一、先来认识一下URLLoader:

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
				layout="absolute" fontSize="12" backgroundGradientAlphas="[1.0, 1.0]" 
				backgroundGradientColors="[#FB7305, #FAE605]" width="621" height="385">	
	<mx:Script>
		<![CDATA[
			import com.mengya.URLLoaderTxt;
			
			internal function doTXT():void{
				var urlLoaderTxt:URLLoaderTxt = new URLLoaderTxt();
			}			
		]]>
	</mx:Script>
	<mx:Button x="49" y="40" label="测试URLLoader,读取文本" width="193" height="30" click="doTXT();"/>
</mx:Application>

 URLLoaderTxt 类如下:

package com.mengya{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.IEventDispatcher;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.net.URLVariables;
	
	public class URLLoaderTxt extends Sprite {
		public function URLLoaderTxt(){
			var loader:URLLoader = new URLLoader();
			//订阅URLLoader的事件
			configListeners(loader);
			var request:URLRequest = new URLRequest("myTxt.txt");
			loader.load(request);
		}
		private function configListeners(dispatcher:IEventDispatcher):void {
			dispatcher.addEventListener(Event.COMPLETE,loaderComplete);
			dispatcher.addEventListener(Event.OPEN,openLoader);
		}
		private function loaderComplete(event:Event):void {
			var urlLoader:URLLoader = URLLoader(event.target);
			trace(urlLoader.data)
			var urlVariables:URLVariables = new URLVariables(urlLoader.data);
			trace(urlVariables.msg);
		}
		private function openLoader(event:Event):void{
			trace("打开连接");
		}
	}
}

 

对URLLoader功能有初步的认识以后完成以上的功能,如下:

mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
				layout="absolute" fontSize="12" backgroundGradientAlphas="[1.0, 1.0]" 
				backgroundGradientColors="[#FB7305, #FAE605]" width="621" height="385"
				applicationComplete="initApp();">	
	<mx:Script>
		<![CDATA[
			import com.mengya.LoadFinishEvent;
			import com.mengya.URLLoaderXML;
			
			[Bindable]
			private var dp:XMLList;
						
			internal function initApp():void{
				//添加自己定义的数据加载完成事件
				URLLoaderXML._eventDispatcher.addEventListener(LoadFinishEvent.LOADFINISHED,onLoadFinished);				
			}
			internal function doXML():void{
				var urlLoaderXML:URLLoaderXML = new URLLoaderXML();
			}
			internal function onLoadFinished(event:LoadFinishEvent):void{
				dp = new XMLList(event.data);
			}

		]]>
	</mx:Script>
	<mx:Button x="49" y="88" label="测试URLLoader,读取XML" width="193" height="30" click="doXML();"/>
	<mx:DataGrid x="49" y="147" width="529" height="193" dataProvider="{dp}">
		<mx:columns>
			<mx:DataGridColumn headerText="姓名" dataField="name" fontFamily="宋体" resizable="true"/>
			<mx:DataGridColumn headerText="电话" dataField="phone" fontFamily="宋体" resizable="true"/>
			<mx:DataGridColumn headerText="邮箱" dataField="email" fontFamily="宋体" resizable="true"/>
		</mx:columns>
	</mx:DataGrid>
</mx:Application>

 自定义事件类LoadFinishEvent如下:

package com.mengya{
	import flash.events.Event;
	//自己定义一个事件,用于发布数据加载完成,将加载完数据随事件一起发布
	public class LoadFinishEvent extends Event{
		public static const LOADFINISHED:String = "Loadfinished";
		public var data:String;
		public function LoadFinishEvent(type:String,
										data:String,
										bubbles:Boolean=false,
										cancelable:Boolean=false){
			this.data = data;
			super(type,bubbles,cancelable);
		}
	} 
}

 

完成发布自定义的事件的类如下:

package com.mengya
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IEventDispatcher;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	
	//这是一个非视图组件,在向服务器获取数据后发布一个自定义的事件,并将数据随着事件一起发布
	public class URLLoaderXML extends Sprite{
		
		public static var _eventDispatcher:EventDispatcher = new EventDispatcher();
				
		public function URLLoaderXML(){
			var loader:URLLoader = new URLLoader();
			//配置对URLoader的事件订阅
			configureListeners(loader);
			var request:URLRequest = new URLRequest("XMLFile.xml");
			try{
				//获取指定的XML数据
				loader.load(request);
			}catch(error:Error){
				trace(error.message);
			}		
		}
		
		private function configureListeners(dispatcher:IEventDispatcher):void{
			//订阅了URLLoader的Event.COMPLETE事件,表示加载完成
			dispatcher.addEventListener(Event.COMPLETE,completeHandler);
		}
		
		public function completeHandler(event:Event):void{
			var urlloader:URLLoader = URLLoader(event.target);
			//urlloader.data已包含加载来的数据
			trace(urlloader.data);
			//发布自定义的事件,并将所加载完成的数据随事件一起发布,用于在视图组件订阅捕获
			var evt:LoadFinishEvent = new LoadFinishEvent(LoadFinishEvent.LOADFINISHED,
														  urlloader.data);	
			_eventDispatcher.dispatchEvent(evt);
		}
	}
}

 

文章评论

程序员都该阅读的书
程序员都该阅读的书
漫画:程序员的工作
漫画:程序员的工作
中美印日四国程序员比较
中美印日四国程序员比较
程序员应该关注的一些事儿
程序员应该关注的一些事儿
程序员和编码员之间的区别
程序员和编码员之间的区别
程序员的一天:一寸光阴一寸金
程序员的一天:一寸光阴一寸金
Web开发者需具备的8个好习惯
Web开发者需具备的8个好习惯
亲爱的项目经理,我恨你
亲爱的项目经理,我恨你
如何区分一个程序员是“老手“还是“新手“?
如何区分一个程序员是“老手“还是“新手“?
什么才是优秀的用户界面设计
什么才是优秀的用户界面设计
2013年中国软件开发者薪资调查报告
2013年中国软件开发者薪资调查报告
60个开发者不容错过的免费资源库
60个开发者不容错过的免费资源库
Google伦敦新总部 犹如星级庄园
Google伦敦新总部 犹如星级庄园
为啥Android手机总会越用越慢?
为啥Android手机总会越用越慢?
Java程序员必看电影
Java程序员必看电影
2013年美国开发者薪资调查报告
2013年美国开发者薪资调查报告
我跳槽是因为他们的显示器更大
我跳槽是因为他们的显示器更大
鲜为人知的编程真相
鲜为人知的编程真相
代码女神横空出世
代码女神横空出世
程序猿的崛起——Growth Hacker
程序猿的崛起——Growth Hacker
为什么程序员都是夜猫子
为什么程序员都是夜猫子
聊聊HTTPS和SSL/TLS协议
聊聊HTTPS和SSL/TLS协议
10个调试和排错的小建议
10个调试和排错的小建议
程序员周末都喜欢做什么?
程序员周末都喜欢做什么?
程序员的鄙视链
程序员的鄙视链
每天工作4小时的程序员
每天工作4小时的程序员
程序员最害怕的5件事 你中招了吗?
程序员最害怕的5件事 你中招了吗?
看13位CEO、创始人和高管如何提高工作效率
看13位CEO、创始人和高管如何提高工作效率
 程序员的样子
程序员的样子
Java 与 .NET 的平台发展之争
Java 与 .NET 的平台发展之争
我是如何打败拖延症的
我是如何打败拖延症的
旅行,写作,编程
旅行,写作,编程
那些争议最大的编程观点
那些争议最大的编程观点
总结2014中国互联网十大段子
总结2014中国互联网十大段子
“懒”出效率是程序员的美德
“懒”出效率是程序员的美德
我的丈夫是个程序员
我的丈夫是个程序员
如何成为一名黑客
如何成为一名黑客
10个帮程序员减压放松的网站
10个帮程序员减压放松的网站
老美怎么看待阿里赴美上市
老美怎么看待阿里赴美上市
程序员必看的十大电影
程序员必看的十大电影
要嫁就嫁程序猿—钱多话少死的早
要嫁就嫁程序猿—钱多话少死的早
初级 vs 高级开发者 哪个性价比更高?
初级 vs 高级开发者 哪个性价比更高?
老程序员的下场
老程序员的下场
十大编程算法助程序员走上高手之路
十大编程算法助程序员走上高手之路
团队中“技术大拿”并非越多越好
团队中“技术大拿”并非越多越好
写给自己也写给你 自己到底该何去何从
写给自己也写给你 自己到底该何去何从
“肮脏的”IT工作排行榜
“肮脏的”IT工作排行榜
5款最佳正则表达式编辑调试器
5款最佳正则表达式编辑调试器
Web开发人员为什么越来越懒了?
Web开发人员为什么越来越懒了?
软件开发程序错误异常ExceptionCopyright © 2009-2015 MyException 版权所有